как сохранять текст из textField в модели и сразу переходить на следующий textField по нажатию ENTER

Question

June 7, 2018, 2:25 p.m.

как сохранять текст из textField в модели и сразу переходить на следующий textField по нажатию ENTER

Rectangle {

    ListView {
         id: listView
         delegate: Item {
            id: cDelegate
            Item {
                Row {
                   ComboBox {
                       delegate: ItemDelegate {
                           Label {
                           //...
                           }
                       }
                   }
            
                   TextField {
                       //...
                        Keys.onEnterPressed: {
                            lModel.currentIndex = lModel.currentIndex + 1;
                            //...
                        }
                        Keys.onReturnPressed: {
                            //...
                        }
                    }
                   
                 }
             }
         }
         model: lModel
         //...
    }
}

We recommend hosting TIMEWEB

Stable hosting, on which the social network EVILEG is located. For projects on Django we recommend VDS hosting.

Subscribe to the discussion2

Section subscription99

Do you like it? Share on social networks!

641

1

0

June 14, 2018, 12:02 a.m.

import QtQuick 2.9
import QtQuick.Window 2.2
import QtQuick.Controls 2.2

Window {
    visible: true
    width: 640
    height: 480
    title: qsTr("Hello World")

    // Модель
    ListModel {
         id: lModel
         ListElement { text: "First Text" }
         ListElement { text: "Second Text" }
         ListElement { text: "Third Text" }
    }

    // Отображение модели с возможностью редактирования
    Item {
        anchors {
            top: parent.top
            left: parent.left
            right: parent.right
            bottom: parent.verticalCenter
        }

        ListView {
            id: listView
            anchors.fill: parent

            delegate: Item {
                anchors.left: parent.left
                anchors.right: parent.right
                height: 48

                TextField {
                    anchors.fill: parent
                    text: model.text
                    Keys.onEnterPressed: commitAndNext()
                    Keys.onReturnPressed: commitAndNext()

                    // Сохраняем информацию из текстового поля в элемент модели
                    // и переходим на следующий элемент
                    function commitAndNext()
                    {
                        model.text = this.text
                        this.nextItemInFocusChain().focus = true
                    }
                }

            }

            model: lModel
        }
    }

    // Read Only вариант отображения модели
    Item {
        anchors {
            top: parent.verticalCenter
            left: parent.left
            right: parent.right
            bottom: parent.bottom
        }

        ListView {
             anchors.fill: parent

             delegate: Text {
                anchors.left: parent.left
                anchors.right: parent.right
                height: 48
                text: model.text
             }

             model: lModel
        }
    }
}

как сохранять текст из textField в модели и сразу переходить на следующий textField по нажатию ENTER

We recommend hosting TIMEWEB

Comments

Actions