Qt - Undocumented QMake - Copying Files

Qt, undocumented, QMake

Qt is quite a large framework and it constantly introduces functionality, which unfortunately either do not have time to document or forget to document.

For example, besides the QQuickItem documentation, I highly recommend watching the sources, or at least the header files. Wonder how many public methods are there that are not described in the documentation, but can be successfully applied, and are very useful in a word.

But now the talk will be about copying files using the functionality that was implemented in Qt 5.6, but at the same time almost nothing is known about it.

Preamble

I already implemented copying files using QMAKE_EXTRA_TARGETS when developing an installer project on QtIFW , which is often advised in various forums.

And this is how the code for copying files looked.

INSTALLER_OFFLINE = $$OUT_PWD/../../InstallerRelease/Hello.offline
INSTALLER_ONLINE = $$OUT_PWD/../../InstallerRelease/Hello.online
 
# Set a variable that should contain the path to the data folder
DESTDIR_WIN = $$PWD/packages/ru.evileg.helloinstaller/data
DESTDIR_WIN ~= s,/,\\,g
# We set the path from where all the application with DLLs will need to be copied
PWD_WIN = $$OUT_PWD/../../HelloRelease
PWD_WIN ~= s,/,\\,g
 
# Before assembling the installers, you must copy the files from the project's output folder along with all the DLLs to the data folder that belongs to the package you are building.
copydata.commands = $(COPY_DIR) $$PWD_WIN $$DESTDIR_WIN
first.depends = $(first) copydata
export(first.depends)
export(copydata.commands)
# we set a custom build target, in which we first perform file compiling and then the rest, which follows the QMake script
QMAKE_EXTRA_TARGETS += first copydata

Quite a monstrous solution, especially if you consider that the syntax of QMake itself is so-so. In addition, setting up copying files using this functionality is also a non-trivial task.

Implementation using the undocumented file_copies module

But the undocumented file_copies module makes everything somewhat simpler and, in terms of setting, looks like the INSTALLS setting.

# Add the file_copies module
CONFIG += file_copies
# Add a variable that describes the copied files.
COPIES += translations
 
# Determine with which extension we need to copy the files and in what way they are located
translations.files = $$files($$PATH_SRC_ROOT/*.qm)
 
# Specify the path where to copy files
translations.path = $$DESTDIR

In this case, we do not need to call the build with the install argument to copy the files as needed for INSTALLS.

That is, we can copy, for example, translation files into the build directory of an exe file to check if the translations work correctly, or something else like that, without full application deployment.

Notes

If desired, you can specify the base path to be trimmed from the source path.

translations.base = $$PWD/target_path

Copying one file did not work, that is, if you write like this

translations.files = $$files($$PATH_SRC_ROOT/application_es.qm)

That file was simply not copied. Perhaps on the most recent versions of Qt, it works stably, but with 5.9.3, on which I tested it, did not work.