Згадав трохи хардкора у хардварі з TWI інтерфейсом, яким займався кілька років тому. Хто б що не говорив, а Assembler відмінно прочищає мозок і розвиває розуміння алгоритмів. Найголовніше, що я засвоїв під час роботи з AVR мікроконтролерами на Assembler, так це те, що всі операції, всі директиви, всі функції повинні писатися в чіткій послідовності. Адже якщо записати дані в регістр не в тій послідовності, Ваша прошивка контролера взагалі не запрацює. А при написанні програмного коду високорівневими мовами часом можна побачити повну байдужість у послідовності виклику функцій і методів, хоча найчастіше в інструкціях до бібліотек можна прочитати, в якій послідовності потрібно ініціалізувати той чи інший функціонал, щоб усе працювало. Але хто їх читав уважно? Добре, якщо Ви дорогий читач прочитали цей абзац, а не скопіпастили відразу програмний код бібліотеки, який представлений нижче.
TWI інтерфейс
Даний тип внутрішньосхемного інтерфейсу є аналогом інтерфейсу I2C , який був розроблений компанією Philips у 1980-х роках. Цей інтерфейс застосовується як апаратний модуль мікроконтролерів Atmega і значно полегшує роботу з шиною I2C, по якій працюють інші пристрої. Назва відмінна від I2C є результатом дії патентного законодавства.
Як і шина I2C , інтерфейс TWI також працює за двома двонаправленими лініями зв'язку: SDA (англ. Serial DAta) та SCL (анлг. Serial CLock). Обидві лінії зв'язку підтягуються у схемі резисторами до харчування, яке зазвичай становить +5 та +3.3 Вольта. Адресний простір у класичному варіанті становить 128 адрес, у розширеному стандарті 1024 адреси.
Існує чотири види значних станів на шині, з яких складається робота інтерфейсу:
- СТАРТ - зміна стану лінії SDA від 1 до 0, при незмінному стані SCL 1
- СТОП - зміна стану лінії SDA від 0 до 1 при незмінному стані SCL в 1
- Передача біта рівного 1 - SDA у стані 1, SCL змінює стан 0-1-0
- Передача біта рівного 0 - SDA у стані 1, SCL змінює стан 0-1-0
Зміна стану SDA при SCL рівному 1 не відіграє жодної ролі та ігнорується.
Шина TWI працює за принципом Ведучий-Відомий. Ведучий подає стартове посилання, після чого починає передачу байта інформації. Як тільки Ведомий прийняв інформацію, він відправляє біт підтвердження. Закінчення передачі визначається стоповой посилкою.
Бібліотека для роботи з TWI інтерфейсом
У цій статті представлена бібліотека для роботи з TWI інтерфейсом, яка призначена для мікроконтролерів Atmega48 , Atmega88 , Atmega168 , Atmega328 . Також бібліотека може застосовуватись для роботи та іншими мікроконтролерами Atmega, які мають TWI інтерфейс.
*Увага. Назви регістрів у різних моделях можуть відрізнятися.
/*
* i2c_lib.asm
*
* Библиотека процедур для шины i2c (Atmega48)
* Библиотека предназначена для использования в качестве подключаемого модуля
* к другим проектам.
*
* Библиотека работает с интерфейсом TWI в avr микроконтроллерах
*
* Библиотека работает с регистром r16
*
* Created: 15.07.2013 23:51:32
* Author: Евгений Легоцкой
*/
;======= Стартовая посылка по шине i2c =================================================
i2c_start:
push r16
ldi r16,(1<<TWINT)|(1<<TWSTA)|(1<<TWEN) ; Выполняем посылку стартовой комбинации
sts TWCR,r16 ; Посылаем полученный байт в TWCR
rcall i2c_wait ; Ожидание формирования start в блоке TWI
pop r16 ; Возвращаем данные в r16 из стека
ret
;======= Стоповая посылка по шине i2c ==================================================
i2c_stop:
push r16
ldi r16,(1<<TWINT)|(1<<TWSTO)|(1<<TWEN) ; Отправляем стоповую посылку
sts TWCR,r16 ; Посылаем полученный байт в TWCR
pop r16 ; Возвращаем данные в r16 из стека
ret
;======= Посылка байта информации по шине i2c ==========================================
i2c_send:
push r16
sts TWDR,r16 ; Записываем передаваемый байт в регистр TWDR
ldi r16,(1<<TWINT)|(1<<TWEN) ; Формируем байт, отвечающий
; за пересылку информационного байта
sts TWCR,r16 ; Посылаем полученный байт в TWCR
rcall i2c_wait ; Ожидание окончания пересылки байта
pop r16 ; Возвращаем данные в r16 из стека
ret
;======= Приём информационного байта по шине i2c =======================================
i2c_receive:
; Принятый байт помещается в регистр r16, поэтому рекомендуется
; продумать программу так, чтобы в этот момент в нём не было
; важной информации, байт не сохраняется в стеке в коде данной
; процедуры
ldi r16,(1<<TWINT)|(1<<TWEN)|(1<<TWEA) ; Формируем байт, отвечающий за прием
sts TWCR,r16 ; Посылаем полученный байт в TWCR
rcall i2c_wait ; Ожидание окончания приёма байта
lds r16,TWDR ; Считываем полученную информацию из TWDR
ret
;======= Приём последнего байта (NACK) =================================================
i2c_receive_last:
; Принятый байт помещается в регистр r16, поэтому рекомендуется
; продумать программу так, чтобы в этот момент в нём не было
; важной информации, байт не сохраняется в стеке в коде данной
; процедуры
ldi r16,(1<<TWINT)|(1<<TWEN) ; Формируем байт, отвечающий за прием информационного байта
sts TWCR,r16 ; Посылаем полученный байт в TWCR
rcall i2c_wait ; Ожидание окончания приёма байта
lds r16,TWDR ; Считываем полученную информацию из TWDR
ret
;======= Ожидание готовности TWI =======================================================
i2c_wait:
lds r16,TWCR ; Загружаем значение из TWCR в r16
sbrs r16,TWINT ; Функция ожидания выполняется до тех пор, пока поднят флаг
; прерывания в 1
rjmp i2c_wait
ret
;=======================================================================================
*Увага. Також для роботи бібліотеки потрібно ініціалізувати Стек мікроконтролера. Наприклад: *
;======= Макросы =========================================================================
; Макрос вывода в порт или регистр
.macro outi
ldi r16, @1
out @0,R16
.endm
;=========================================================================================
RESET:
outi SPL,Low(RAMEND) ; Инициализация стека
outi SPH,High(RAMEND)
