Не заполняется модель в ListView данными json

Народ ну помогите. Код взят из хабра, практически не изменен, но он не работает. Точнее js отрабатывает, в консоль летит выхлоп с json данными, но модель не заполняется. Код работал точно, т.к брал его же раньше и все было нормально. Может были какие то изменения в самой библиотеке. З.Ы. qt 5.10

Вот код

import QtQuick 2.9
import QtQuick.Window 2.2
Window {
    id: mainM

    property int userId: XXX //здесь ваш user_id
    property var friends

    width: 320
    height: 640
    color: 'skyblue'
    visible: true

        function getFriends() {
                var requ = new XMLHttpRequest()
                requ.open('POST', 'https://api.vk.com/method/friends.get')
                requ.onreadystatechange = function() {
                    if(requ.readyState === XMLHttpRequest.DONE) {
                        if(requ.status && requ.status === 200) {
                           console.log("response", requ.responseText)
                           var results = JSON.parse(requ.responseText)
                           mainM.friends = results.response
                        } else {
                            console.log('HTTP:', requ.status, requ.responseText)
                        }
                    }
                }
                requ.setRequestHeader('Content-Type', 'application/x-www-form-urlencoded')
                requ.send('&fields=photo_medium' + '&user_id=' + mainM.userId + '&v=5.73')

        }

    ListView {
        id: view

        anchors.margins: 10
        anchors.fill: parent
        model: friends
        spacing: 10

        delegate: Rectangle {
            width: view.width
            height: 100
            anchors.horizontalCenter: parent.horizontalCenter
            color: 'white'
            border {
                color: 'lightgray'
                width: 2
            }
            radius: 10

            Row {
                anchors.margins: 10
                anchors.fill: parent
                spacing: 10

                Image {
                    id: image

                    height: parent.height
                    fillMode: Image.PreserveAspectFit
                    source: modelData['photo_medium']
                }

                Text {
                    width: parent.width - image.width - parent.spacing
                    anchors.verticalCenter: parent.verticalCenter
                    elide: Text.ElideRight
                    renderType: Text.NativeRendering
                    text: "%1 %2".arg(modelData['first_name']).arg(modelData['last_name'])
                }
            }
        }
    }

    Component.onCompleted: {
        getFriends()
    }
}

function getFriends() {
    var requ = new XMLHttpRequest()
    requ.open('POST', 'https://api.vk.com/method/friends.get')
    requ.onreadystatechange = function() {
        if(requ.readyState === XMLHttpRequest.DONE) {
            if(requ.status && requ.status === 200) {
               var results = JSON.parse(requ.responseText)
               mainM.friends = results.response.items
            } else {
                console.log('HTTP:', requ.status, requ.responseText)
            }
        }
    }
    requ.setRequestHeader('Content-Type', 'application/x-www-form-urlencoded')
    requ.send('&fields=photo_medium' + '&user_id=' + mainM.userId + '&v=5.73')
}