Чтение и запись данных в QML файлах

Question

HelgeIDҚаз. 31, 2017, 6:57 Т.Ж.

Чтение и запись данных в QML файлах

Здравствуйте EVILEG ! Спасибо за отличный сайт с ценной информацией! У меня такой вопрос: Хочу прочитать и записать данные с одного QML файла в другой QML файл. Проблемы в принципе нет (если только из одного файла в другой), но как получить эти данные еще в всех остальных QML файлах, или как иметь доступ к этим данным с любого QML - файла?

Собственно код:

main.qml

import QtQuick 2.6
import QtQuick.Window 2.2
import QtQuick.Controls 1.4

Window {
    visible: true
    width: 200
    height: 100
    title: qsTr("QML WIN")

    Loader {
        anchors.fill: parent
        source: "MyResource1.qml"
    }

    Loader {
        anchors.fill: parent
        source: "MyResource2.qml"
    }

    Button {
        anchors.centerIn: parent
        text: "Show"
        onClicked: {
            console.log(myData.val)
        }
    }

    MyData {
        id: myData
        anchors.centerIn: parent
    }
}

MyData.qml

import QtQuick 2.0

Item {
    property int val: 0
}

MyResource1.qml

import QtQuick 2.0
import QtQuick.Controls 1.4

Item {
    Button {
        anchors.left: parent.left
        text: "100"
        onClicked: {
            myData.val = 100
            console.log(myData.val)
        }
    }

    MyData {
        id: myData
        anchors.centerIn: parent
    }
}

MyResource2.qml

import QtQuick 2.0
import QtQuick.Controls 1.4

Item {
    Button {
        anchors.right: parent.right
        text: "200"
        onClicked: {
            myData.val = 200
            console.log(myData.val)
        }
    }

    MyData {
        id: myData
        anchors.centerIn: parent
    }
}

Конкретно по примеру, что мне нужно: Что бы при нажатии клавиши Show консоль показывала 100 или 200. Я не знаю как так реализовать, поэтому спрашиваю помощи знающих людей. Использую Qt 5.9.

Рекомендуем хостинг TIMEWEB

Стабильный хостинг, на котором располагается социальная сеть EVILEG. Для проектов на Django рекомендуем VDS хостинг.

Талқылауға жазылыңыз3

Бөлімге жазылу99

Ол саған ұнайды ма? Әлеуметтік желілерде бөлісіңіз!

Қаз. 31, 2017, 8:14 Т.Ж.

Совет не совсем по теме, если вы юзаете 5.9 версию то контролы уже пора юзать 2.0
То что вы используете 1.4 это старая и не очень хороша в работе версия.
На остальное Евгений вам ответит))

Қаз. 31, 2017, 12:59 Т.Қ.
Жауап шешім ретінде белгіленді.

День добрый!

Здесь нужно использовать сигналы из файлов MyResource1.qml и MyResource2.qml

MyResource1.qml

import QtQuick 2.0
import QtQuick.Controls 1.4

Item {
    signal newValue(var value) // Добавляем сигнал

    Button {
        anchors.left: parent.left
        text: "100"
        onClicked: {
            myData.val = 100
            console.log(myData.val)
            newValue(myData.val) // Вызываем сигнал, передавая в него значение
        }
    }

    MyData {
        id: myData
        anchors.centerIn: parent
    }
}

MyResource2.qml

import QtQuick 2.0
import QtQuick.Controls 1.4

Item {
    signal newValue(var value) // Добавляем сигнал

    Button {
        anchors.right: parent.right
        text: "200"
        onClicked: {
            myData.val = 200
            console.log(myData.val)
            newValue(myData.val) // Вызываем сигнал, передавая в него новое значение
        }
    }

    MyData {
        id: myData
        anchors.centerIn: parent
    }
}

Далее, используя объект Connections , подключаемся к сигналам объектов в лоадерах.

main.cpp

import QtQuick 2.6
import QtQuick.Window 2.2
import QtQuick.Controls 1.4

Window {
    visible: true
    width: 200
    height: 100
    title: qsTr("QML WIN")

    Loader {
        id: loader1
        anchors.fill: parent
        source: "MyResource1.qml"
    }

    Connections {
        target: loader1.item // Коннект к объекту MyResource1
        onNewValue: { // Обработчик сигнала
            myData.val = value // Установка значения
        }
    }

    Loader {
        id: loader2
        anchors.fill: parent
        source: "MyResource2.qml"
    }

    Connections { // Аналогично подключаемся в MyResource2
        target: loader2.item
        onNewValue: {
            myData.val = value
        }
    }

    Button {
        anchors.centerIn: parent
        text: "Show"
        onClicked: {
            console.log(myData.val)
        }
    }

    MyData {
        id: myData
        anchors.centerIn: parent
    }
}

H

HelgeID → BlinCT
#

Қар. 1, 2017, 8:12 Т.Ж.

да-да BlinCT # , спасибо за замечание, надо помнить об этом :)

H

HelgeID → Evgenii Legotckoi
#

Қар. 1, 2017, 8:26 Т.Ж.

Ура! Спасибо за оперативность и за быстрый ответ. Это как раз то что мне надо. Респект вам ребята!!! :)

Пікірлер

Тек рұқсаты бар пайдаланушылар ғана пікір қалдыра алады.
Кіріңіз немесе Тіркеліңіз