QML. Обращение из одного обьекта к свойствам другого обьекта

сигналы, qml, файлы, коннекты между файлами

Rectangle
{
    id: rectangle1
Column
    {
        anchors.top: togglebutton.bottom
        anchors.right: parent.right
        Switch
        {
            id: testswitch
            checked: true
            onClicked:
            {
    
               if(checked)
                {
                    testtext.flag = true
                }
            }
        }
    }
}

RowLayout
{
    id: timerValue
    RowLayout
    {
        TextField
        {
            id:testtext
            inputMask: ("NN:NN")
            text: "00:00"
            property bool flag: false
            readOnly: flag
        }
    }
}

Рекомендуем хостинг TIMEWEB

Стабильный хостинг, на котором располагается социальная сеть EVILEG. Для проектов на Django рекомендуем VDS хостинг.

Объекты, которые представлены данными файлами, должны где-то объявляться. Например, в файле main.

Да, они обьявлены в main.qml

pplicationWindow
{
    Content1  //Заполнение данными из файла Content1
    {
        id: content1
        anchors.top: parent.top
        anchors.left: parent.left
        anchors.right: parent.right
        height: dp(40)
        color: "#4cd964"
    }
 
    Content2  //Заполнение данными из файла Content2
    {
        id:content2
        anchors.top: parent.top
        anchors.topMargin: dp(80)
        anchors.leftMargin: dp(30)
    }
}

И само собою все эти файлы объявленный в qml.qrc

Здесь нужно использовать сигналы для передачи информации из одного объекта в другой. У меня есть пример с использованием сигналов в QML. Также не хватает property alias в файле Content2, который уже свяжет property bool flag.
А для данной задачи решение следующее:

Content1.qml

import QtQuick 2.0
import QtQuick.Controls 1.4
 
Rectangle
{
    id: rectangle1
    signal checked(bool check) // Объявляем сигнатуру сигнала
 
    Column
    {
        anchors.right: parent.right
        Switch
        {
            id: testswitch
            checked: true
            onClicked:
            {
                // При клике по переключателю испускаем сигнал с состоянием
                // переключателя
                rectangle1.checked(checked);
            }
        }
    }
}

Content2.qml

import QtQuick 2.0
import QtQuick.Controls 1.4
import QtQuick.Layouts 1.1
 
RowLayout
{
    id: timerValue
 
    // Прописываем алиас к свойству testtext
    property alias flag: testtext.flag
 
    RowLayout
    {
        TextField
        {
            id:testtext
            inputMask: ("NN:NN")
            text: "00:00"
            property bool flag: false
            readOnly: flag
        }
    }
}

main.qml

import QtQuick 2.6
import QtQuick.Controls 1.4
 
ApplicationWindow
{
    id: app
    width: 300
    height: 400
    visible: true
 
    Content1  //Заполнение данными из файла Content1
    {
        id: content1
        anchors.top: parent.top
        anchors.left: parent.left
        anchors.right: parent.right
        height: 40
        color: "#4cd964"
 
        // Добавляем обработчик испускаемого сигнала, ...
        onChecked: {
            // в котором свойству второго объекта
            // присваиваем состояние переключателя
            content2.flag = check
        }
    }
 
    Content2  //Заполнение данными из файла Content2
    {
        id:content2
        anchors.top: parent.top
        anchors.topMargin: 80
        anchors.leftMargin: 30
    }
}

Здесь нужно использовать сигналы для передачи информации

Спасибо. Все оказалось не так тривиально, как казалось на первый взгляд. Будем изучать дальше).