Заполнение TabBar

Question

BlinCTҚаз. 7, 2019, 12:28 Т.Қ.

Заполнение TabBar

Всем привет.
Хочу в Qml в TabBar заполнить каждую из вкладок контентом из отдельных файлов.
Знаю что можно через Loader но у меня почему то все равно в каждой вкладке контент из первой вкладки.

TabButton {
                text: qsTr("Test_1")
            }
            TabButton {
                text: qsTr("Test_2")
            }
            TabButton {
                text: qsTr("Test_3")
            }

            onCurrentIndexChanged: {
                switch (currentIndex)
                {
                case 0:
                    loader.source = "qrc:/General.qml"
                    break;
                case 1:
                    loader.source = "qrc:/Test_2.qml"
                    break;
                case 2:
                    loader.source = "qrc:/Test_3.qml"
                    break;
                }

            }

        Loader {
            id: loader
            anchors.fill: parent
            source: "qrc:/General.qml"
        }

Может кто подскажет, я где то ошибку допускаю? И может есть другие способы заполнения?
Спасибо.

Рекомендуем хостинг TIMEWEB

Стабильный хостинг, на котором располагается социальная сеть EVILEG. Для проектов на Django рекомендуем VDS хостинг.

Талқылауға жазылыңыз2

Бөлімге жазылу249

Ол саған ұнайды ма? Әлеуметтік желілерде бөлісіңіз!

Қаз. 7, 2019, 2:52 Т.Қ.

Привет. Может лучше использовать вариант из примеров Qt?

TabBar {
    id: bar
    width: parent.width
    TabButton {
        text: qsTr("Home")
    }
    TabButton {
        text: qsTr("Discover")
    }
    TabButton {
        text: qsTr("Activity")
    }
}

StackLayout {
    width: parent.width
    currentIndex: bar.currentIndex
    Item {
        id: homeTab
    }
    Item {
        id: discoverTab
    }
    Item {
        id: activityTab
    }
}

BlinCT → Evgenii Legotckoi
#

Қаз. 7, 2019, 3:39 Т.Қ.

Ну в принципе да, тут ты прав, но все равно остается ситуация что контент что находится в каждом табе вылезает за пределы не только таба но и TabBar.
Вот 2 скрина первого и второго таба. Сам TabBar находится под ComboBox

Қаз. 7, 2019, 3:42 Т.Қ.

Запомни, если контент вылезает за пределы родителя, то попробуй включить clip: true в родителе, чтобы срезать весь контент пределами родителя.

BlinCT → Evgenii Legotckoi
#

Қаз. 7, 2019, 4:28 Т.Қ.

Если я правильно понимаю то это надо у TabBar включить?
Если так то это не помогло(

Қаз. 8, 2019, 2:38 Т.Ж.

StackLayout {
    width: parent.width
    currentIndex: bar.currentIndex
    Item {
        id: homeTab
        clip: true
    }
    Item {
        id: discoverTab
        clip: true
    }
    Item {
        id: activityTab
        clip: true
    }
}

BlinCT → Evgenii Legotckoi
#

Қаз. 8, 2019, 3:07 Т.Ж.

Нет, не помогло. Вообще перестает что либо отображатся.

Evgenii Legotckoi → BlinCT
#

Қаз. 8, 2019, 3:16 Т.Ж.
Жауап шешім ретінде белгіленді.

Ну а голову включить и вёрстку написать правильно?

import QtQuick 2.9
import QtQuick.Window 2.2
import QtQuick.Controls 2.5
import QtQuick.Layouts 1.12

Window {
    visible: true
    width: 640
    height: 480
    title: qsTr("Hello World")

    TabBar {
        id: bar
        width: parent.width
        TabButton {
            text: qsTr("Home")
        }
        TabButton {
            text: qsTr("Discover")
        }
        TabButton {
            text: qsTr("Activity")
        }
    }

    StackLayout {
        width: parent.width
        currentIndex: bar.currentIndex
        anchors.top: bar.bottom
        anchors.left: parent.left
        anchors.right: parent.right
        anchors.bottom: parent.bottom

        Item {
            id: homeTab
            clip: true

            ListView {
                anchors.fill: parent
                model: ListModel {
                    ListElement {
                        name: "Bill Smith"
                        number: "555 3264"
                    }
                    ListElement {
                        name: "John Brown"
                        number: "555 8426"
                    }
                    ListElement {
                        name: "Sam Wise"
                        number: "555 0473"
                    }
                }

                delegate: Text {
                    text: name + ": " + number
                }
            }
        }
        Item {
            id: discoverTab
            clip: true
            ListView {
                anchors.fill: parent
                model: ListModel {
                    ListElement {
                        name: "Bill Smith"
                        number: "555 3264"
                    }
                    ListElement {
                        name: "John Brown"
                        number: "555 8426"
                    }
                }

                delegate: Text {
                    text: name + ": " + number
                }
            }
        }
        Item {
            id: activityTab
            clip: true
            ListView {
                anchors.fill: parent
                model: ListModel {
                    ListElement {
                        name: "Bill Smith"
                        number: "555 3264"
                    }
                }

                delegate: Text {
                    text: name + ": " + number
                }
            }
        }
    }
}

Пікірлер

Тек рұқсаты бар пайдаланушылар ғана пікір қалдыра алады.
Кіріңіз немесе Тіркеліңіз