Simple Tracker project. Part 2: project structure

Iscander Che, Simple Tracker, Qt, C++

The general structure is shown below.

I changed the name of the project. But in the titles of articles and tags, I will still leave "Simple tracker" so that there is no confusion.

The project consists of client and server subprojects and a testing subproject. The main project file looks like this.

TEMPLATE = subdirs

CONFIG   += ordered

SUBDIRS += ICTrackerServer ICTrackerClient tests

It is worth noting the common.pri file, which is visible to the client and server subprojects (and will also be included in the tests as needed). There I entered additional directives, peeped in other projects.

# Переменная PWD разворачивается в путь к файлу *.pro/*.pri, в котором используется
BUILD_DIR = $${PWD}/build

# В зависимости от типа билда, debug или release, устанавливаем соответствующее
# значение переменной BUILD_TYPE
CONFIG(release, debug|release){
    message(Release)
    BUILD_TYPE = release
}else{
    message(Debug)
    BUILD_TYPE = debug
}

DEST_BINS = $${BUILD_DIR}/$${BUILD_TYPE}

# В зависимости от платформы, на которой собираем проект, устанавливаем
# расположение исполняемых файлов.
# Регулярное выражение "s,/,\\,g" в SOME_VAR ~= s,/,\\,g означает
# "заменить в переменной SOME_VAR прямой слэш ("/") на обратный слэш ("\")".
win32 {
    DEST_BINS ~= s,/,\\,g
    DESTDIR = $${DEST_BINS}
}

linux {
    DESTDIR = $${DEST_BINS}
}

# Остальные файлы, которые генерируются по ходу сборки, выносим за пределы репозитория.
# Переменная OUT_PWD разворачивается в путь построения билда,
# заданный в Qt Creator в настройках проекта.
MOC_DIR        = $${OUT_PWD}/$${BUILD_TYPE}/moc
UI_DIR         = $${OUT_PWD}/$${BUILD_TYPE}/ui
UI_HEADERS_DIR = $${OUT_PWD}/$${BUILD_TYPE}/ui
UI_SOURCES_DIR = $${OUT_PWD}/$${BUILD_TYPE}/ui
OBJECTS_DIR    = $${OUT_PWD}/$${BUILD_TYPE}/obj
RCC_DIR        = $${OUT_PWD}/$${BUILD_TYPE}/rcc

Thus, when compiling a project in debug mode, the folder structure may look something like this.

Next to the source folders, a build folder is formed with two subfolders debug and release, where only executable files are written.

The remaining files are taken out of the project tree.

I placed the common.pri file in the root of the project and included it in the pro files of the subprojects using the include directive.

include(../common.pri)

Now let's look at subprojects.

The client, apart from the pro and pri files, has only main.cpp. Since the client is assumed to be console, most likely, apart from auxiliary functions, nothing else is needed.

It remains only to add network support to the pro-file.

QT += network

The server has more tasks, and therefore its structure is more complicated. There is a TrackerServer class here, which is responsible for creating the tracker GUI and server operation. The image also shows the DataBase class, which is responsible for working with the database. Also, in the course of development, classes will be added to implement dialog boxes.

Here in the pro-file, in addition to network support, you need to add SQL support.

QT += sql network

The tests subproject itself will consist of subprojects, so the following is written in the pro file:

TEMPLATE = subdirs

CONFIG   += ordered

SUBDIRS +=

With the structure of the project, in the first approximation, it is finished. In the next part, I will describe the database and its testing.