Заполнение TabBar

Question

BlinCTOct. 7, 2019, 12:28 p.m.

Заполнение TabBar

Всем привет.
Хочу в Qml в TabBar заполнить каждую из вкладок контентом из отдельных файлов.
Знаю что можно через Loader но у меня почему то все равно в каждой вкладке контент из первой вкладки.

TabButton {
                text: qsTr("Test_1")
            }
            TabButton {
                text: qsTr("Test_2")
            }
            TabButton {
                text: qsTr("Test_3")
            }

            onCurrentIndexChanged: {
                switch (currentIndex)
                {
                case 0:
                    loader.source = "qrc:/General.qml"
                    break;
                case 1:
                    loader.source = "qrc:/Test_2.qml"
                    break;
                case 2:
                    loader.source = "qrc:/Test_3.qml"
                    break;
                }

            }

        Loader {
            id: loader
            anchors.fill: parent
            source: "qrc:/General.qml"
        }

Может кто подскажет, я где то ошибку допускаю? И может есть другие способы заполнения?
Спасибо.

We recommend hosting TIMEWEB

Stable hosting, on which the social network EVILEG is located. For projects on Django we recommend VDS hosting.

Subscribe to the discussion2

Section subscription238

Do you like it? Share on social networks!

Oct. 7, 2019, 2:52 p.m.

Привет. Может лучше использовать вариант из примеров Qt?

TabBar {
    id: bar
    width: parent.width
    TabButton {
        text: qsTr("Home")
    }
    TabButton {
        text: qsTr("Discover")
    }
    TabButton {
        text: qsTr("Activity")
    }
}

StackLayout {
    width: parent.width
    currentIndex: bar.currentIndex
    Item {
        id: homeTab
    }
    Item {
        id: discoverTab
    }
    Item {
        id: activityTab
    }
}

BlinCT → Evgenii Legotckoi
#

Oct. 7, 2019, 3:39 p.m.

Ну в принципе да, тут ты прав, но все равно остается ситуация что контент что находится в каждом табе вылезает за пределы не только таба но и TabBar.
Вот 2 скрина первого и второго таба. Сам TabBar находится под ComboBox

Oct. 7, 2019, 3:42 p.m.

Запомни, если контент вылезает за пределы родителя, то попробуй включить clip: true в родителе, чтобы срезать весь контент пределами родителя.

BlinCT → Evgenii Legotckoi
#

Oct. 7, 2019, 4:28 p.m.

Если я правильно понимаю то это надо у TabBar включить?
Если так то это не помогло(

Oct. 8, 2019, 2:38 a.m.

StackLayout {
    width: parent.width
    currentIndex: bar.currentIndex
    Item {
        id: homeTab
        clip: true
    }
    Item {
        id: discoverTab
        clip: true
    }
    Item {
        id: activityTab
        clip: true
    }
}

BlinCT → Evgenii Legotckoi
#

Oct. 8, 2019, 3:07 a.m.

Нет, не помогло. Вообще перестает что либо отображатся.

Evgenii Legotckoi → BlinCT
#

Oct. 8, 2019, 3:16 a.m.
The answer was marked as a solution.

Ну а голову включить и вёрстку написать правильно?

import QtQuick 2.9
import QtQuick.Window 2.2
import QtQuick.Controls 2.5
import QtQuick.Layouts 1.12

Window {
    visible: true
    width: 640
    height: 480
    title: qsTr("Hello World")

    TabBar {
        id: bar
        width: parent.width
        TabButton {
            text: qsTr("Home")
        }
        TabButton {
            text: qsTr("Discover")
        }
        TabButton {
            text: qsTr("Activity")
        }
    }

    StackLayout {
        width: parent.width
        currentIndex: bar.currentIndex
        anchors.top: bar.bottom
        anchors.left: parent.left
        anchors.right: parent.right
        anchors.bottom: parent.bottom

        Item {
            id: homeTab
            clip: true

            ListView {
                anchors.fill: parent
                model: ListModel {
                    ListElement {
                        name: "Bill Smith"
                        number: "555 3264"
                    }
                    ListElement {
                        name: "John Brown"
                        number: "555 8426"
                    }
                    ListElement {
                        name: "Sam Wise"
                        number: "555 0473"
                    }
                }

                delegate: Text {
                    text: name + ": " + number
                }
            }
        }
        Item {
            id: discoverTab
            clip: true
            ListView {
                anchors.fill: parent
                model: ListModel {
                    ListElement {
                        name: "Bill Smith"
                        number: "555 3264"
                    }
                    ListElement {
                        name: "John Brown"
                        number: "555 8426"
                    }
                }

                delegate: Text {
                    text: name + ": " + number
                }
            }
        }
        Item {
            id: activityTab
            clip: true
            ListView {
                anchors.fill: parent
                model: ListModel {
                    ListElement {
                        name: "Bill Smith"
                        number: "555 3264"
                    }
                }

                delegate: Text {
                    text: name + ": " + number
                }
            }
        }
    }
}

Comments

Only authorized users can post comments.
Please, Log in or Sign up