Qt WinAPI - Lektion 004. QtIFW - Automatisierung von WinDeployQt und Build-Installationsprogramme mit Qt Installer Framework

Qt, QtIFW, Qt Installer Framework, windeployqt

Ein guter Programmierer ist ein fauler Programmierer. Wenn es die Möglichkeit gibt, etwas zu automatisieren, dann müssen Sie es unbedingt tun. Beispielsweise können Sie windeployqt automatisch ausführen, indem Sie Online- und Offline-Installationsprogramme zusammenstellen, sowie das Anwendungs-Repository mit Qt Installer Framework und schwarzer Magie QMake .

Um dies auf die schönste Weise zu tun, ist es notwendig, dass das Projekt mit der Struktur Unterverzeichnisse organisiert ist, also aus mehreren Projekten besteht. Wir müssen nicht bei jedem Build des Projekts Installer erstellen. Daher wird das Installer-Projekt separat sein.

Aber lassen wir die windeployqt-Automatisierung im Hauptprojekt.

Projektstruktur

Wir haben also ein Projekt mit zwei Teilprojekten:

1. Hello.pro - Anwendungsprojekt
2. Installer.pro - Installationsprojekt

Das Hauptprojekt ist das häufigste „Hello world“, aber das größte Interesse gilt dem QMake-Skript, das für das windeployqt der Anwendung verantwortlich ist.

Das zweite Projekt hat eine minimale Struktur zum Erstellen von Offline- und Online-Installern sowie zum Erstellen eines Repositorys. Das QMake-Skript im Projektprofil enthält auch die notwendigen Informationen, um den Build der Installer zu automatisieren.

WinDeployQt-Automatisierung

HelloInstaller.pro

Diese Datei hat den traditionellen Inhalt für Projekt-Unterverzeichnisse.

TEMPLATE = subdirs

CONFIG += ordered

SUBDIRS += \
    Hello \
    Installer

Hallo.pro

Zusätzlich zur üblichen Angabe der Assemblyverzeichnisse der ausführbaren Datei sowie anderer Projektausgabedateien führt dieses QMake-Skript das Dienstprogramm windeployqt aus.

QT += core
QT -= gui

CONFIG += c++11

TARGET = Hello
CONFIG += console
CONFIG -= app_bundle

TEMPLATE = app

# Выбираем директорию сборки исполняемого файла
# в зависимости от режима сборки проекта
CONFIG(debug, debug|release) {
    DESTDIR = $$OUT_PWD/../../HelloDebug
} else {
    DESTDIR = $$OUT_PWD/../../HelloRelease
}
# разделяем по директориям все выходные файлы проекта
MOC_DIR = ../common/build/moc
RCC_DIR = ../common/build/rcc
UI_DIR = ../common/build/ui
unix:OBJECTS_DIR = ../common/build/o/unix
win32:OBJECTS_DIR = ../common/build/o/win32
macx:OBJECTS_DIR = ../common/build/o/mac

# в зависимости от режима сборки проекта
# запускаем win deploy приложения в целевой директории, то есть собираем все dll
CONFIG(debug, debug|release) {
    QMAKE_POST_LINK = $$(QTDIR)/bin/windeployqt $$OUT_PWD/../../HelloDebug
} else {
    QMAKE_POST_LINK = $$(QTDIR)/bin/windeployqt $$OUT_PWD/../../HelloRelease
}

SOURCES += main.cpp

Wenn mit der Angabe der Zusammenstellung des Ordners der ausführbaren Datei alles klar ist, lassen Sie uns herausfinden, was passiert, wenn windeployqt ausgeführt wird.

QMAKE_POST_LINK ist eine Anweisung, die angibt, was nach dem Erstellen des Projekts zu tun ist. Das heißt, was wir tun, nachdem die ausführbare Datei erstellt wurde.

$$(QTDIR) ist eine Variable, die den Pfad zum Qt-Build-Bundle enthält. In meinem Fall ist es D:\Qt\5.7\mingw53_32.

Um windeployqt auszuführen, ist es nicht erforderlich, die ausführbare Datei anzugeben, es reicht aus, den Ordner, in dem sich diese Datei befindet, als Argument anzugeben. Als Ergebnis wird nach Abschluss der Projekterstellung die für die Anwendung erforderliche DLL automatisch erstellt und neben der ausführbaren Datei platziert .

Gebäudeinstallateure und Repository

Die Zusammenstellung der Installer und des Online-Repositorys des Projekts erfolgt mit dem Qt Installer Framework, das Dienstprogramme sowohl zum Erstellen der Installer selbst als auch zum Vorbereiten des Anwendungs-Repositorys enthält.

Für die Assemblierung werden zwei Dienstprogramme aus diesem Framework verwendet:

• binarycreator - Dienstprogramm zum Erstellen des Installationsprogramms;
• repogen - Dienstprogramm zum Vorbereiten eines Online-Repositorys.

Bevor wir uns mit dem QMake-Skript befassen, wollen wir uns die Konfigurationsdateien und die Verzeichnisstruktur zum Erstellen von Installern ansehen.

Verzeichnisaufbau

Betrachten Sie die Projektstruktur:

• config - enthält die Konfigurationsdatei des Installationsprogramms:
• config.xml - diese Datei enthält Informationen über das Remote-Repository, die Version, den Projektnamen usw.
• Pakete - die die Pakete enthalten, aus denen die Installationsprogramme erstellt werden, zum Beispiel:
• ru.evileg.helloinstaller - Verzeichnis des ersten Pakets
• meta - ein Verzeichnis, das Installationsskripts enthält, die bestimmte Funktionen beschreiben, z. B. das Schließen der aktiven Instanz der Anwendung, wenn die Anwendung aktualisiert wird, oder das Schreiben von Informationen in die Systemregistrierung.
• package.xml - in der Mindestversion ist diese Datei erforderlich, die die Version und das Erstellungsdatum des Projekts beschreibt. Diese Informationen werden benötigt, um die Datei Updates.xml zu generieren, die in das Online-Repository gestellt wird.
• Daten - In diesem Verzeichnis müssen die ausführbare Datei und alle erforderlichen DLLs, Ressourcendateien, Übersetzungsdateien usw. abgelegt werden. Das heißt, alles, was zum Erstellen einer funktionierenden Anwendung benötigt wird.
• ru.evileg.ecolor - sowie beispielsweise das Verzeichnis des zweiten Pakets mit Inhalten, die ähnlich aufgebaut sind wie die vorherigen Optionen.

config.xml

Eine Datei, die Dienstinformationen über den Herausgeber, den Installationspfad der Anwendung, ihre Version und ihren Namen beschreibt. Es enthält auch Informationen über die Adresse des Remote-Repositorys. Diese Informationen sind für das Online-Installationsprogramm und das Offline-Installationsprogramm gleich. Schließlich müssen wir unter anderem auch die Anwendung aktualisieren, daher benötigen beide Versionen der Installer Informationen über das Remote-Repository.

<?xml version="1.0" encoding="UTF-8"?>
<Installer>
    <Name>Hello Installer</Name>
    <Version>1.0.0</Version>
    <Title>1.0.0 Installer</Title>
    <Publisher>EVILEG</Publisher>
    <StartMenuDir>HelloInstaller</StartMenuDir>
    <TargetDir>@RootDir@Program Files (x86)\EVILEG\HelloInstaller</TargetDir>
        <AllowSpaceInPath>true</AllowSpaceInPath>
    <RemoteRepositories>
        <Repository>
            <Url>http://www.evileg.ru/software/helloinstaller/</Url>
        </Repository>
    </RemoteRepositories>
</Installer>

• Installer - generierter Installer
• Name - Anwendungsname
• Version - Anwendungsversion
• Titel – Der Titel des Installationsfensters
• Herausgeber - Herausgeber
• StartMenuDir - gibt die Produktgruppe an, zu der die Anwendung im Windows-Startmenü gehört.
• TargetDir - Anwendungsinstallationsordner; @RootDir@ - Stammordner. In diesem Fall C:\
• AllowSpaceInPath - Leerzeichen im Verzeichnispfad zulassen
• RemoteRepositories - Liste der Repositories
• Repository - eines der Online-Repositorys, es können mehrere vorhanden sein oder sie können sogar ersetzt werden
• URL - Repository-Adresse

Paket.xml

Hier werden bereits zusätzliche Informationen zum Verfahren zum Installieren der Anwendung im System angezeigt, dh zum Beispiel das Vorhandensein bestimmter Formulare, Fenster und Installationsskripts zum Eingeben von Informationen in die Registrierung. Außerdem wurden Informationen zum Veröffentlichungsdatum der Anwendung hinzugefügt, die auch in der Datei Updates.xml. abgelegt werden.

Diese Datei muss in jedem Paket enthalten sein. Das Installationsprogramm bietet möglicherweise die Möglichkeit, eine Reihe von Komponenten zu installieren, erinnern Sie sich an das Qt-Installationsprogramm, es gibt viele Punkte. Dementsprechend stellt jedes derartige Paket einen eigenen Artikel dar.

<?xml version="1.0" encoding="UTF-8"?>
<Package>
    <DisplayName>Hello Installer</DisplayName>
    <Description>The main component</Description>
    <Version>1.0.0</Version>
    <ReleaseDate>2016-07-30</ReleaseDate>
        <Default>true</Default>
    <Name>ru.evileg.helloinstaller</Name>
    <ForcedInstallation>true</ForcedInstallation>
    <RequiresAdminRights>true</RequiresAdminRights>
</Package>

• DisplayName - Komponentenname. Erforderliches Tag.
• Beschreibung - Beschreibung der Komponente. Erforderliches Tag.
• Version - Version der Komponente. Erforderliches Tag.
• ReleaseDate - Veröffentlichungsdatum. Erforderliches Tag.
• Standard - Auswahl der Standardkomponente, dh die Komponente für die Installation ist ausgewählt oder nicht.
• Name - Paketkennung in Form eines Domänennamens. Erforderliches Tag.
• ForcedInstallation – gibt an, dass die Komponente installiert werden muss und der Benutzer sie nicht von der Installation ausschließen kann
• RequiresAdminRights - gibt an, dass das Paket mit Administratorrechten installiert werden muss. Das Feld ist optional. Und das Interessanteste ist, dass der Installer während der Arbeit diese Administratorrechte verlieren kann. Das heißt, für einige Aktionen müssen Sie erneut Administratorrechte vom Benutzer anfordern.

Installer.pro

Hier ist eine Variante mit Zusammenstellung von Installern in separaten Ordnern für Release - und Debug -Versionen. Sowie das Vorbereiten des Repositorys für die Release -Version.

Verwenden Sie zum Erstellen des Offline-Installationsprogramms das Dienstprogramm binarycreator mit den folgenden Parametern:

• --offline-only - wie der Name schon sagt, weist darauf hin, dass wir ein Offline-Installationsprogramm erstellen
• -c - gibt den Pfad zur Konfigurationsdatei an
• -p - gibt den Pfad zum Ordner mit Paketen an, während der Arbeit wird QtIFW herausfinden, wie Pakete im Installationsprogramm erstellt werden, wobei ihre Konfigurationsdateien und Skripte aus dem Metaordner berücksichtigt werden

Hinweis. Für die Online-Version des Installationsprogramms ist alles gleich, nur das Argument --offline-only wird durch --online-only ersetzt.**

Und um das Repository vorzubereiten, verwenden wir das Dienstprogramm repogen mit den folgenden Parametern:

• -p - gibt einen Ordner mit Paketen an
• -i - gibt Pakete an, die in das Installationsprogramm eingeschlossen werden sollen
• -update - gibt an, dass Sie das Repository im folgenden Pfad aktualisieren müssen. Wenn sich in diesem Pfad kein Repository befindet, wird ein neues erstellt.

# Before run make project, need to put executable file and dlls into
# $$PWD/installer/packages/ru.evileg.helloinstaller/data

TEMPLATE = aux

# В зависимости от режима сборки, определяем, куда именно будут собираться инсталляторы
CONFIG(debug, debug|release) {
    INSTALLER_OFFLINE = $$OUT_PWD/../../InstallerDebug/Hello.offline
    INSTALLER_ONLINE = $$OUT_PWD/../../InstallerDebug/Hello.online
    DESTDIR_WIN = $$PWD/packages/ru.evileg.helloinstaller/data
    DESTDIR_WIN ~= s,/,\\,g
    PWD_WIN = $$OUT_PWD/../../HelloDebug
    PWD_WIN ~= s,/,\\,g

    copydata.commands = $(COPY_DIR) $$PWD_WIN $$DESTDIR_WIN
    first.depends = $(first) copydata
    export(first.depends)
    export(copydata.commands)
    QMAKE_EXTRA_TARGETS += first copydata
} else {
    # Задаём переменные, которые будут содержать пути с названиями инсталляторов
    INSTALLER_OFFLINE = $$OUT_PWD/../../InstallerRelease/Hello.offline
    INSTALLER_ONLINE = $$OUT_PWD/../../InstallerRelease/Hello.online

    # Задаём переменную, которая должна содержать путь к папке с данными
    DESTDIR_WIN = $$PWD/packages/ru.evileg.helloinstaller/data
    DESTDIR_WIN ~= s,/,\\,g
    # Задаём путь откуда всё приложение с DLL-ками нужно будет скопировать
    PWD_WIN = $$OUT_PWD/../../HelloRelease
    PWD_WIN ~= s,/,\\,g

    # Прежде, чем выполнять сборку инсталляторов, необходимо скопировать файлы
    # из выходной папки проекта вместе со всеми DLL в папку data, которая относится
    # к собираемому пакету
    copydata.commands = $(COPY_DIR) $$PWD_WIN $$DESTDIR_WIN
    first.depends = $(first) copydata
    export(first.depends)
    export(copydata.commands)
    # задаём кастомную цель сборки, при которой сначала выполним компирование файлов
    # а потом уже и остальное, что следует по скрипту QMake
    QMAKE_EXTRA_TARGETS += first copydata
}

# Создаём цель по сборке Оффлайн Инсталлятора
INPUT = $$PWD/config/config.xml $$PWD/packages
offlineInstaller.depends = copydata
offlineInstaller.input = INPUT
offlineInstaller.output = $$INSTALLER_OFFLINE
offlineInstaller.commands = $$(QTDIR)/../../QtIFW2.0.3/bin/binarycreator --offline-only -c $$PWD/config/config.xml -p $$PWD/packages ${QMAKE_FILE_OUT}
offlineInstaller.CONFIG += target_predeps no_link combine

QMAKE_EXTRA_COMPILERS += offlineInstaller

# Создаём цель по сборке Онлайн Инсталлятора
INPUT = $$PWD/config/config.xml $$PWD/packages
onlineInstaller.depends = copydata
onlineInstaller.input = INPUT
onlineInstaller.output = $$INSTALLER_ONLINE
onlineInstaller.commands = $$(QTDIR)/../../QtIFW2.0.3/bin/binarycreator --online-only -c $$PWD/config/config.xml -p $$PWD/packages ${QMAKE_FILE_OUT}
onlineInstaller.CONFIG += target_predeps no_link combine

QMAKE_EXTRA_COMPILERS += onlineInstaller

# репозиторий будем собирать только в случае режима release
CONFIG(release, debug|release) {
    # Сборку репозитория производим после того, как были собраны Инсталляторы
    # Для этого воспользуемся QMAKE_POST_LINK вместо QMAKE_EXTRA_COMPILERS
    # Поскольку он хорошо для этого подходит
    QMAKE_POST_LINK += $$(QTDIR)/../../QtIFW2.0.3/bin/repogen -p $$PWD/packages -i ru.evileg.helloinstaller --update $$OUT_PWD/../../repository
}

DISTFILES += \
    packages/ru.evileg.helloinstaller/meta/package.xml \
    config/config.xml

Laden Sie das Archiv mit dem Projekt herunter Qt Installer Framework example

Videoanleitung