Evgenii Legotckoi
Evgenii Legotckoi21 августа 2015 г. 21:30

TWI интерфейс в микроконтроллерах AVR Atmega

Вспомнил немного хардкора в хардваре с TWI интерфейсом, которым занимался несколько лет назад. Кто бы что ни говорил, а Assembler отлично прочищает мозги и развивает понимание алгоритмов. Самое главное, что я усвоил при работе с AVR микроконтроллерами на Аssembler, так это то, что все операции, все директивы, все функции должны писаться в чёткой последовательности. Ведь если записать данные в регистр не в той последовательности, то Ваша прошивка контроллера вообще не заработает. А при написании программного кода на высокоуровневых языках порой можно увидеть полное безразличие в последовательности вызова функций и методов, хотя зачастую в инструкциях к библиотекам можно прочесть, в какой последовательности нужно инициализировать тот или иной функционал, чтобы всё работало. Но кто бы их читал внимательно? Хорошо, если Вы дорогой читатель прочитали этот абзац, а не скопипастили сходу себе программный код библиотеки, который представлен ниже.


TWI интерфейс

Данный тип внутрисхемного интерфейса является аналогом интерфейса I2C , который был разработан компанией Philips в 1980-х годах. Этот интерфейс применяется как аппаратный модуль микроконтроллеров Atmega и значительно облегчает работу с шиной I2C , по которой работают другие устройства. Название отличное от I2C является результатом воздействия патентного законодательства.

Как и шина I2C , интерфейс TWI также работает по двум двунаправленным линиям связи: SDA (англ. Serial DAta) и SCL (анлг. Serial CLock). Обе линии связи подтягиваются в схеме резисторами к питанию, которое обычно составляет +5 и +3.3 Вольта. Адресное пространство в классическом варианте составляет 128 адресов, в расширенном стандарте 1024 адреса.

Существует четыре вида значимых состояний на шине, из которых состоит работа интерфейса:

  • СТАРТ - изменение состояния линии SDA от 1 к 0, при неизменном состоянии SCL в 1
  • СТОП - изменение состояния линии SDA от 0 к 1 , при неизменном состоянии SCL в 1
  • Передача бита равного 1 - SDA в состоянии 1, SCL изменяет состояние 0-1-0
  • Передача бита равного 0 - SDA в состоянии 1, SCL изменяет состояние 0-1-0

Изменение состояния SDA при SCL равном 1 не играет никакой роли и игнорируется.

Шина TWI работает по принципу Ведущий-Ведомый. Ведущий подаёт стартовую посылку, после чего начинает передачу байта информации. Как только Ведомый принял информацию, он отправляет бит подтверждения. Окончание передачи данных определяется стоповой посылкой.

Библиотека для работы с TWI интерфейсом

В данной статье представлена библиотека для работы с TWI интерфейсом, которая предназначена для микроконтроллеров Atmega48 , Atmega88 , Atmega168 , Atmega328 . Также библиотека может применяться для работы и другими микроконтроллерами Atmega, которые имеют TWI интерфейс.

Внимание. Названия регистров в различных моделях могут отличаться.

/*
 * i2c_lib.asm
 *
 * Библиотека процедур для шины i2c (Atmega48)
 * Библиотека предназначена для использования в качестве подключаемого модуля 
 * к другим проектам. 
 *
 * Библиотека работает с интерфейсом TWI в avr микроконтроллерах
 *
 * Библиотека работает с регистром r16
 *
 *  Created: 15.07.2013 23:51:32
 *   Author: Евгений Легоцкой
 */ 

 ;======= Стартовая посылка по шине i2c =================================================
 i2c_start:
    push    r16                 
    ldi     r16,(1<<TWINT)|(1<<TWSTA)|(1<<TWEN)  ; Выполняем посылку стартовой комбинации
    sts     TWCR,r16      ; Посылаем полученный байт в TWCR
    rcall   i2c_wait      ; Ожидание формирования start в блоке TWI
    pop     r16           ; Возвращаем данные в r16 из стека
        ret
 ;======= Стоповая посылка по шине i2c ==================================================
 i2c_stop:
    push    r16                 
    ldi     r16,(1<<TWINT)|(1<<TWSTO)|(1<<TWEN)  ; Отправляем стоповую посылку
    sts     TWCR,r16      ; Посылаем полученный байт в TWCR
    pop     r16           ; Возвращаем данные в r16 из стека
    ret
 ;======= Посылка байта информации по шине i2c ==========================================
 i2c_send:
    push    r16                 
    sts     TWDR,r16      ; Записываем передаваемый байт в регистр TWDR
    ldi     r16,(1<<TWINT)|(1<<TWEN)  ; Формируем байт, отвечающий 
                                      ; за пересылку информационного байта
    sts     TWCR,r16      ; Посылаем полученный байт в TWCR
    rcall   i2c_wait      ; Ожидание окончания пересылки байта
    pop     r16           ; Возвращаем данные в r16 из стека
    ret
 ;======= Приём информационного байта по шине i2c =======================================
 i2c_receive:
 ; Принятый байт помещается в регистр r16, поэтому рекомендуется    
 ; продумать программу так, чтобы в этот момент в нём не было 
 ; важной информации, байт не сохраняется в стеке в коде данной 
 ; процедуры
    ldi     r16,(1<<TWINT)|(1<<TWEN)|(1<<TWEA)  ; Формируем байт, отвечающий за прием 
    sts     TWCR,r16      ; Посылаем полученный байт в TWCR
    rcall   i2c_wait      ; Ожидание окончания приёма байта
    lds     r16,TWDR      ; Считываем полученную информацию из TWDR
    ret
 ;======= Приём последнего байта (NACK) =================================================
 i2c_receive_last:
 ; Принятый байт помещается в регистр r16, поэтому рекомендуется    
 ; продумать программу так, чтобы в этот момент в нём не было 
 ; важной информации, байт не сохраняется в стеке в коде данной 
 ; процедуры
    ldi     r16,(1<<TWINT)|(1<<TWEN) ; Формируем байт, отвечающий за прием информационного байта
    sts     TWCR,r16      ; Посылаем полученный байт в TWCR
    rcall   i2c_wait      ; Ожидание окончания приёма байта
    lds     r16,TWDR      ; Считываем полученную информацию из TWDR
    ret
 ;======= Ожидание готовности TWI =======================================================
 i2c_wait:
    lds     r16,TWCR      ; Загружаем значение из TWCR в r16
    sbrs    r16,TWINT     ; Функция ожидания выполняется до тех пор, пока поднят флаг 
                          ; прерывания в 1
    rjmp    i2c_wait
    ret
 ;=======================================================================================

Внимание. Также для работы библиотеки требуется инициализировать Стек микроконтроллера. Например следующим образом:

 ;======= Макросы =========================================================================
 ; Макрос вывода в порт или регистр
 .macro outi             
        ldi r16, @1 
        out @0,R16
 .endm
 ;=========================================================================================
 RESET:
    outi    SPL,Low(RAMEND)    ; Инициализация стека
    outi    SPH,High(RAMEND)
Рекомендуем хостинг TIMEWEB
Рекомендуем хостинг TIMEWEB
Стабильный хостинг, на котором располагается социальная сеть EVILEG. Для проектов на Django рекомендуем VDS хостинг.

Вам это нравится? Поделитесь в социальных сетях!

Комментарии

Только авторизованные пользователи могут публиковать комментарии.
Пожалуйста, авторизуйтесь или зарегистрируйтесь
B

C++ - Тест 002. Константы

  • Результат:16баллов,
  • Очки рейтинга-10
B

C++ - Тест 001. Первая программа и типы данных

  • Результат:46баллов,
  • Очки рейтинга-6
FL

C++ - Тест 006. Перечисления

  • Результат:80баллов,
  • Очки рейтинга4
Последние комментарии
k
kmssr9 февраля 2024 г. 1:43
Qt Linux - Урок 001. Автозапуск Qt приложения под Linux как сделать автозапуск для флэтпака, который не даёт создавать файлы в ~/.config - вот это вопрос ))
АК
Анатолий Кононенко5 февраля 2024 г. 8:50
Qt WinAPI - Урок 007. Работаем с ICMP Ping в Qt Без строки #include <QRegularExpressionValidator> в заголовочном файле не работает валидатор.
EVA
EVA25 декабря 2023 г. 17:30
Boost - статическая линковка в CMake проекте под Windows Ошибка LNK1104 часто возникает, когда компоновщик не может найти или открыть файл библиотеки. В вашем случае, это файл libboost_locale-vc142-mt-gd-x64-1_74.lib из библиотеки Boost для C+…
J
JonnyJo25 декабря 2023 г. 15:38
Boost - статическая линковка в CMake проекте под Windows Сделал всё по-как у вас, но выдаёт ошибку [build] LINK : fatal error LNK1104: не удается открыть файл "libboost_locale-vc142-mt-gd-x64-1_74.lib" Хоть убей, не могу понять в чём дел…
G
Gvozdik19 декабря 2023 г. 4:01
Qt/C++ - Урок 056. Подключение библиотеки Boost в Qt для компиляторов MinGW и MSVC Для решения твой проблемы добавь в файл .pro строчку "LIBS += -lws2_32" она решит проблему , лично мне помогло.
Сейчас обсуждают на форуме
P
Pisych27 февраля 2023 г. 11:04
Как получить в массив значения из связанной модели? Спасибо, разобрался:))
AC
Alexandru Codreanu19 января 2024 г. 18:57
QML Обнулить значения SpinBox Доброго времени суток, не могу разобраться с обнулением значение SpinBox находящего в делегате. import QtQuickimport QtQuick.ControlsWindow { width: 640 height: 480 visible: tr…
BlinCT
BlinCT27 декабря 2023 г. 15:57
Растягивать Image на парент по высоте Ну и само собою дял включения scrollbar надо чтобы был Flickable. Так что выходит как то так Flickable{ id: root anchors.fill: parent clip: true property url linkFile p…
Дмитрий
Дмитрий10 января 2024 г. 11:18
Qt Creator загружает всю оперативную память Проблема решена. Удалось разобраться с помощью утилиты strace. Запустил ее: strace ./qtcreator Начал выводиться весь лог работы креатора. В один момент он начал считывать фай…
Evgenii Legotckoi
Evgenii Legotckoi12 декабря 2023 г. 13:48
Побуквенное сравнение двух строк Добрый день. Там случайно не высылается этот сигнал textChanged ещё и при форматировани текста? Если решиать в лоб, то можно просто отключать сигнал/слотовое соединение внутри слота и …

Следите за нами в социальных сетях